Inhoud
- Zoek in Excel op meerdere criteria
- We extraheren de 2e, 3e, etc. waarden met behulp van VERT.ZOEKEN
- Haal alle herhalingen van de gewenste waarde op
- XNUMXD zoeken op bekende rij en kolom
- Meerdere VERT.ZOEKEN in één formule gebruiken
- Dynamische vervanging van gegevens uit verschillende tabellen met VERT.ZOEKEN en INDIRECT
In het tweede deel van onze tutorial over de functie VPR (VERT.ZOEKEN) in Excel, we zullen een paar voorbeelden analyseren die u zullen helpen alle kracht te richten VPR om de meest ambitieuze Excel-taken op te lossen. De voorbeelden gaan ervan uit dat je al een basiskennis hebt van hoe deze functie werkt. Zo niet, dan is het misschien interessant om te beginnen met het eerste deel van deze tutorial, waarin de syntaxis en het basisgebruik worden uitgelegd. VPR. Laten we beginnen.
Zoek in Excel op meerdere criteria
Functie VPR in Excel is een echt krachtig hulpmiddel voor het uitvoeren van zoekopdrachten naar een bepaalde waarde in een database. Er is echter een belangrijke beperking: dankzij de syntaxis kunt u naar slechts één waarde zoeken. Wat als u op meerdere voorwaarden wilt zoeken? Hieronder vindt u de oplossing.
Voorbeeld 1: Zoek op 2 verschillende criteria
Stel dat we een lijst met bestellingen hebben en we willen vinden Hoeveelheid goederen (Aantal.), Gebaseerd op twee criteria – Klantnaam (Klant) и productnaam (Product). De zaak wordt gecompliceerd door het feit dat elk van de kopers verschillende soorten goederen heeft besteld, zoals blijkt uit de onderstaande tabel:
normale functie VPR werkt niet in dit scenario omdat het de eerste waarde retourneert die het vindt die overeenkomt met de opgegeven opzoekwaarde. Als u bijvoorbeeld de hoeveelheid van een artikel wilt weten Snoepgoed'besteld door de koper Jeremy Heuvel, schrijf de volgende formule:
=VLOOKUP(B1,$A$5:$C$14,3,FALSE)
=ВПР(B1;$A$5:$C$14;3;ЛОЖЬ)
- deze formule geeft het resultaat terug 15overeenkomend met het product: Appels, omdat dit de eerste waarde is die overeenkomt.
Er is een eenvoudige oplossing: maak een extra kolom waarin u alle gewenste criteria kunt combineren. In ons voorbeeld zijn dit de kolommen Klantnaam (Klant) и productnaam (Product). Vergeet niet dat de samengevoegde kolom altijd de meest linkse kolom in het zoekbereik moet zijn, aangezien het de linkerkolom is die de functie VPR wordt opgezocht bij het zoeken naar een waarde.
U voegt dus een hulpkolom toe aan de tabel en kopieert de volgende formule over al zijn cellen: =B2&C2. Als u wilt dat de tekenreeks leesbaarder is, kunt u de gecombineerde waarden scheiden met een spatie: =B2&» «&C2. Daarna kunt u de volgende formule gebruiken:
=VLOOKUP("Jeremy Hill Sweets",$A$7:$D$18,4,FALSE)
=ВПР("Jeremy Hill Sweets";$A$7:$D$18;4;ЛОЖЬ)
or
=VLOOKUP(B1,$A$7:$D$18,4,FALSE)
=ВПР(B1;$A$7:$D$18;4;ЛОЖЬ)
Waar is de cel? B1 bevat de aaneengeschakelde waarde van het argument opzoekwaarde (lookup_value) en 4 – Argumenten kolomindex_getal (column_number), dwz het nummer van de kolom met de op te halen gegevens.
Voorbeeld 2: VERT.ZOEKEN volgens twee criteria waarbij de tabel op een ander blad wordt bekeken
Als u de hoofdtabel (Hoofdtabel) moet bijwerken door gegevens toe te voegen uit de tweede tabel (Lookup-tabel), die zich op een ander blad of in een andere Excel-werkmap bevindt, dan kunt u de gewenste waarde direct verzamelen in de formule die u invoegt in de hoofdtabel.
Net als in het vorige voorbeeld heb je een hulpkolom nodig in de opzoektabel met de gecombineerde waarden. Deze kolom moet de meest linkse kolom in het zoekbereik zijn.
Dus de formule met VPR zou zo kunnen zijn:
=VLOOKUP(B2&" "&C2,Orders!$A&$2:$D$2,4,FALSE)
=ВПР(B2&" "&C2;Orders!$A&$2:$D$2;4;ЛОЖЬ)
Hier bevatten kolommen B en C respectievelijk klantnamen en productnamen, en de link Bestellingen!$A&$2:$D$2 definieert een tabel om op te zoeken in een ander blad.
Om de formule leesbaarder te maken, kunt u het weergavebereik een naam geven, en dan ziet de formule er veel eenvoudiger uit:
=VLOOKUP(B2&" "&C2,Orders,4,FALSE)
=ВПР(B2&" "&C2;Orders;4;ЛОЖЬ)
Om de formule te laten werken, moeten de waarden in de meest linkse kolom van de tabel die u bekijkt, op precies dezelfde manier worden gecombineerd als in de zoekcriteria. In de bovenstaande afbeelding hebben we de waarden u2bu2band gecombineerd en er een spatie tussen geplaatst, op dezelfde manier als u moet doen in het eerste argument van de functie (BXNUMX & "" & CXNUMX).
Onthouden! Functie VPR beperkt tot 255 tekens, kan het niet zoeken naar een waarde die langer is dan 255 tekens. Houd hier rekening mee en zorg ervoor dat de lengte van de gewenste waarde deze limiet niet overschrijdt.
Ik ben het ermee eens dat het toevoegen van een hulpkolom niet de meest elegante en niet altijd acceptabele oplossing is. Je kunt hetzelfde doen zonder de helperkolom, maar daarvoor heb je een veel complexere formule nodig met een combinatie van functies INDEX (INDEX) en MATCH (MEER BLOOTGESTELD).
We extraheren de 2e, 3e, etc. waarden met behulp van VERT.ZOEKEN
Dat weet je al VPR kan slechts één overeenkomende waarde retourneren, meer bepaald de eerste gevonden. Maar wat als deze waarde meerdere keren wordt herhaald in de bekeken array en u de 2e of 3e daarvan wilt extraheren? Wat als alle waarden? Het probleem lijkt ingewikkeld, maar de oplossing bestaat!
Stel dat de ene kolom van de tabel de namen van de klanten bevat (Klantnaam), en de andere kolom de producten (Product) die ze hebben gekocht. Laten we proberen het 2e, 3e en 4e artikel te vinden dat door een bepaalde klant is gekocht.
De gemakkelijkste manier is om een hulpkolom toe te voegen voor de kolom klantnaam en vul het met klantnamen met het herhalingsnummer van elke naam, bijvoorbeeld, Jan Doe1, Jan Doe2 enz. We zullen de truc doen met nummering met behulp van de functie COUNTIF (AANTAL.ALS), aangezien de klantnamen in kolom B staan:
=B2&COUNTIF($B$2:B2,B2)
=B2&СЧЁТЕСЛИ($B$2:B2;B2)
Daarna kunt u de normale functie gebruiken VPRom de gewenste bestelling te vinden. Bijvoorbeeld:
- VIND DE PLEK DIE PERFECT VOOR JOU IS 2 e artikel besteld door de klant Dan Brown:
=VLOOKUP("Dan Brown2",$A$2:$C$16,3,FALSE)=ВПР("Dan Brown2";$A$2:$C$16;3;ЛОЖЬ) - VIND DE PLEK DIE PERFECT VOOR JOU IS 3 e artikel besteld door de klant Dan Brown:
=VLOOKUP("Dan Brown3",$A$2:$C$16,3,FALSE)=ВПР("Dan Brown3";$A$2:$C$16;3;ЛОЖЬ)
U kunt zelfs een celverwijzing invoeren als opzoekwaarde in plaats van tekst, zoals weergegeven in de volgende afbeelding:
Als u alleen op zoek bent naar 2-e herhaling, je kunt het doen zonder de hulpkolom door een complexere formule te maken:
=IFERROR(VLOOKUP($F$2,INDIRECT("$B$"&(MATCH($F$2,Table4[Customer Name],0)+2)&":$C16"),2,FALSE),"")
=ЕСЛИОШИБКА(ВПР($F$2;ДВССЫЛ("$B$"&(ПОИСКПОЗ($F$2;Table4[Customer Name];0)+2)&":$C16");2;ИСТИНА);"")
In deze formule:
- $ F $ 2 – een cel met de naam van de koper (deze is ongewijzigd, let op – de link is absoluut);
- $B$ – kolom klantnaam;
- Table4 – Uw tafel (deze plaats kan ook een regulier assortiment zijn);
- $ C16 – de eindcel van je tabel of bereik.
Deze formule vindt alleen de tweede overeenkomende waarde. Als u de resterende herhalingen wilt extraheren, gebruikt u de vorige oplossing.
Als je een lijst met alle overeenkomsten nodig hebt - de functie VPR dit is geen helper, omdat het slechts één waarde tegelijk retourneert - periode. Maar Excel heeft een functie INDEX (INDEX), die deze taak gemakkelijk aankan. Hoe zo'n formule eruit zal zien, leert u in het volgende voorbeeld.
Haal alle herhalingen van de gewenste waarde op
Zoals hierboven vermeld VPR kan niet alle dubbele waarden uit het gescande bereik halen. Om dit te doen, hebt u een iets complexere formule nodig, bestaande uit verschillende Excel-functies, zoals: INDEX (INHOUDSOPGAVE), SMALL (KLEIN) en RIJ (LIJN)
De onderstaande formule vindt bijvoorbeeld alle herhalingen van de waarde uit cel F2 in het bereik B2:B16 en retourneert het resultaat van dezelfde rijen in kolom C.
{=IFERROR(INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3)),"")}
{=ЕСЛИОШИБКА(ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3));"")}
Voer deze matrixformule in meerdere aangrenzende cellen in, zoals de cellen F4: F8zoals weergegeven in de onderstaande afbeelding. Het aantal cellen moet gelijk zijn aan of groter zijn dan het maximaal mogelijke aantal herhalingen van de gezochte waarde. Vergeet niet te klikken Ctrl + Shift + Enterom de matrixformule correct in te voeren.
Als je geïnteresseerd bent om te begrijpen hoe het werkt, gaan we wat dieper in op de details van de formule:
Deel 1:
IF($F$2=B2:B16,ROW(C2:C16)-1,"")
ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"")
$F$2=B2:B16 – vergelijk de waarde in cel F2 met elk van de waarden in het bereik B2:B16. Als er een overeenkomst wordt gevonden, wordt de uitdrukking STRING(C2:C16)-1 geeft het nummer van de corresponderende regel terug (waarde -1 kunt u de kopregel niet opnemen). Als er geen overeenkomsten zijn, is de functie IF (IF) retourneert een lege tekenreeks.
Functie resultaat IF (IF) er zal zo'n horizontale array zijn: {1,"",3,"",5,"","","","","","",12,"","",""}
Deel 2:
ROW()-3
СТРОКА()-3
Hier de functie RIJ (LINE) fungeert als een extra teller. Omdat de formule is gekopieerd naar de cellen F4:F9, trekken we het getal af 3 van functie resultaat om waarde te krijgen 1 in de cel F4 (regel 4, trek 3) af om . te krijgen 2 in de cel F5 (regel 5, trek 3) af, enzovoort.
Deel 3:
SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
Functie SMALL (KLEINE) retouren n-oh de kleinste waarde in de gegevensreeks. In ons geval, welke positie (van de kleinste) naar terugkeer wordt bepaald door de functie RIJ (LINE) (zie deel 2). Dus, voor een cel F4 functie KLEIN({matrix},1) Retourneren 1 e (kleinste) array-element, dwz 1. voor cel F5 Retourneren 2 e het kleinste element in de array, dat wil zeggen 3, Etc.
Deel 4:
INDEX($C$2:$C$16,SMALL(IF($F$2=B2:B16,ROW(C2:C16)-1,""),ROW()-3))
ИНДЕКС($C$2:$C$16;НАИМЕНЬШИЙ(ЕСЛИ($F$2=B2:B16;СТРОКА(C2:C16)-1;"");СТРОКА()-3))
Functie INDEX (INDEX) retourneert eenvoudig de waarde van een specifieke cel in een array C2:C16. voor cel F4 functie INDEX($€2:€€16) zal terugkeren AppelsVoor F5 functie INDEX($€2:€€16) zal terugkeren Snoepgoed' enzovoort.
Deel 5:
IFERROR()
ЕСЛИОШИБКА()
Ten slotte plaatsen we de formule in de functie IFFOUT (IFERROR), omdat het onwaarschijnlijk is dat u tevreden zult zijn met de foutmelding #AT (#N/A) als het aantal cellen waarin de formule wordt gekopieerd kleiner is dan het aantal dubbele waarden in het bereik dat wordt bekeken.
XNUMXD zoeken op bekende rij en kolom
Het uitvoeren van een XNUMXD-zoekopdracht in Excel omvat het zoeken naar een waarde op een bekend rij- en kolomnummer. Met andere woorden, u extraheert de celwaarde op de kruising van een bepaalde rij en kolom.
Laten we dus naar onze tabel gaan en een formule schrijven met een functie VPR, die informatie zal vinden over de kosten van citroenen die in maart worden verkocht.
Er zijn verschillende manieren om een zoekopdracht uit te voeren. Bekijk de mogelijkheden en kies degene die het beste bij je past.
VLOOKUP- en MATCH-functies
U kunt een heleboel functies gebruiken VPR (VERT.ZOEKEN) en MEER BLOOTGESTELD (MATCH) om de waarde op het snijpunt van de velden te vinden productnaam (string) en Maand (kolom) van de betreffende array:
=VLOOKUP("Lemons",$A$2:$I$9,MATCH("Mar",$A$1:$I$1,0),FALSE)
=ВПР("Lemons";$A$2:$I$9;ПОИСКПОЗ("Mar";$A$1:$I$1;0);ЛОЖЬ)
De bovenstaande formule is een reguliere functie VPR, die zoekt naar een exacte overeenkomst met de waarde "Citroenen" in cellen A2 tot en met A9. Maar aangezien u niet weet in welke kolom de verkopen van maart staan, kunt u het kolomnummer voor het derde functieargument niet instellen. VPR. In plaats daarvan wordt de functie gebruikt MEER BLOOTGESTELDom deze kolom te definiëren.
MATCH("Mar",$A$1:$I$1,0)
ПОИСКПОЗ("Mar";$A$1:$I$1;0)
Vertaald in mensentaal betekent deze formule:
- We zijn op zoek naar de karakters “Mar” – argument opzoekwaarde (opzoekwaarde);
- Zoeken in cellen van A1 tot I1 – argument zoek_array (opzoek_array);
- Exacte overeenkomst retourneren – argument match_type (overeenkomst_type).
gebruik 0 in het derde argument zeg je functies MEER BLOOTGESTELD zoek naar de eerste waarde die exact overeenkomt met de waarde die u zoekt. Dit is gelijk aan de waarde Juist (FALSE) voor het vierde argument VPR.
Zo kunt u in Excel een tweerichtingszoekformule maken, ook wel tweedimensionaal zoeken of bidirectioneel zoeken genoemd.
SOMPRODUCT-functie
Functie SUMPRODUCT (SOMPRODUCT) retourneert de som van de producten van de geselecteerde arrays:
=SUMPRODUCT(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar"),$A$2:$I$9)
=СУММПРОИЗВ(($A$2:$A$9="Lemons")*($A$1:$I$1="Mar");$A$2:$I$9)
INDEX- en MATCH-functies
In het volgende artikel zal ik deze functies in detail uitleggen, dus voor nu kun je deze formule gewoon kopiëren:
=INDEX($A$2:$I$9,MATCH("Lemons",$A$2:$A$9,0),MATCH("Mar",$A$1:$I$1,0))
=ИНДЕКС($A$2:$I$9;ПОИСКПОЗ("Lemons";$A$2:$A$9;0);ПОИСКПОЗ("Mar";$A$1:$I$1;0))
Benoemde bereiken en de operator voor snijpunten
Als je niet van al die complexe Excel-formules houdt, vind je deze visuele en gedenkwaardige manier misschien leuk:
- Selecteer de tafel, open het tabblad Formules (Formules) en klik op Creëer vanuit selectie (Maken vanuit selectie).
- Controleer de dozen Bovenste rij (op de regel hierboven) en Linker kolom (in de kolom aan de linkerkant). Microsoft Excel wijst namen toe aan de bereiken van de waarden in de bovenste rij en linkerkolom van uw spreadsheet. U kunt nu rechtstreeks met deze namen zoeken zonder formules te maken.
- Schrijf in een lege cel =rijnaam kolomnaam, bijvoorbeeld als volgt:
= Citroenen Mar
… of vice versa:
=Mar Citroenen
Onthoud dat de rij- en kolomnamen moeten worden gescheiden door een spatie, wat in dit geval werkt als de intersectieoperator.
Wanneer u een naam invoert, toont Microsoft Excel een tooltip met een lijst met overeenkomende namen, net zoals wanneer u een formule invoert.
- Media Enter en controleer het resultaat
Over het algemeen zal het resultaat van een tweedimensionale zoekopdracht hetzelfde zijn, welke van de bovenstaande methoden u ook kiest:
Meerdere VERT.ZOEKEN in één formule gebruiken
Het komt voor dat de hoofdtabel en de opzoektabel geen enkele kolom gemeen hebben, en dit voorkomt dat u de gebruikelijke functie gebruikt VPR. Er is echter nog een andere tabel die niet de informatie bevat waarin we geïnteresseerd zijn, maar die een gemeenschappelijke kolom heeft met de hoofdtabel en de opzoektabel.
Laten we eens kijken naar het volgende voorbeeld. We hebben een hoofdtabel met een kolom Artikelnummer (nieuw), waar u een kolom met de bijbehorende prijzen uit een andere tabel wilt toevoegen. Daarnaast hebben we 2 opzoektabellen. De eerste (opzoektabel 1) bevat bijgewerkte nummers Artikelnummer (nieuw) en productnamen, en de tweede (opzoektabel 2) - productnamen en oude nummers Artikelnummer (oud).
Om prijzen uit de tweede opzoektabel toe te voegen aan de hoofdtabel, moet u een actie uitvoeren die bekend staat als dubbel VPR of genest VPR.
- Schrijf een functie VPR, die de productnaam in de tabel vindt Opzoektabel 1gebruik SKU, als de gewenste waarde:
=VLOOKUP(A2,New_SKU,2,FALSE)=ВПР(A2;New_SKU;2;ЛОЖЬ)Here Nieuw_SKU – genoemd bereik $A:$B in de tafel Opzoektabel 1, 2 – dit is kolom B, waarin de namen van de goederen staan (zie de afbeelding hierboven)
- Schrijf een formule om prijzen uit een tabel in te voegen Opzoektabel 2 gebaseerd op bekende productnamen. Plak hiervoor de formule die u eerder hebt gemaakt als de opzoekwaarde voor de nieuwe functie VPR:
=VLOOKUP(VLOOKUP(A2,New_SKU,2,FALSE),Price,3,FALSE)=ВПР(ВПР(A2;New_SKU;2;ЛОЖЬ);Price;3;ЛОЖЬ)Here Prijs – genoemd bereik $ A: $ C in de tafel Opzoektabel 2, 3 is kolom C met prijzen.
De onderstaande afbeelding toont het resultaat dat wordt geretourneerd door de formule die we hebben gemaakt:
Dynamische vervanging van gegevens uit verschillende tabellen met VERT.ZOEKEN en INDIRECT
Laten we eerst verduidelijken wat we bedoelen met de uitdrukking "Dynamische vervanging van gegevens uit verschillende tabellen" om ervoor te zorgen dat we elkaar correct begrijpen.
Er zijn situaties waarin er meerdere bladen zijn met gegevens van hetzelfde formaat en het nodig is om de benodigde informatie uit een bepaald blad te halen, afhankelijk van de waarde die in een bepaalde cel is ingevoerd. Ik denk dat het makkelijker is om dit met een voorbeeld uit te leggen.
Stel je voor dat je verkooprapporten hebt voor meerdere regio's met dezelfde producten en in hetzelfde formaat. U wilt verkoopcijfers voor een bepaalde regio vinden:
Als u slechts twee van dergelijke rapporten heeft, kunt u een schandelijk eenvoudige formule met functies gebruiken VPR и IF (IF) om het gewenste rapport te selecteren om te zoeken:
=VLOOKUP($D$2,IF($D3="FL",FL_Sales,CA_Sales),2,FALSE)
=ВПР($D$2;ЕСЛИ($D3="FL";FL_Sales;CA_Sales);2;ЛОЖЬ)
Waar:
- $D$2 is een cel die de naam van het product bevat. Merk op dat we hier absolute verwijzingen gebruiken om te voorkomen dat de opzoekwaarde wordt gewijzigd bij het kopiëren van de formule naar andere cellen.
- $ D3 is een cel met de naam van de regio. We gebruiken een absolute kolomverwijzing en een relatieve rijverwijzing omdat we van plan zijn de formule naar andere cellen in dezelfde kolom te kopiëren.
- FL_Sales и CA_Verkoop – de namen van de tabellen (of benoemde bereiken) die de bijbehorende verkooprapporten bevatten. U kunt natuurlijk de gebruikelijke bladnamen en celbereikverwijzingen gebruiken, bijvoorbeeld 'FL-blad'!$A$3:$B$10, maar benoemde bereiken zijn veel handiger.
Als er echter veel van dergelijke tabellen zijn, is de functie IF is niet de beste oplossing. In plaats daarvan kunt u de functie INDIRECTE (INDIRECT) om terug te keren naar het gewenste zoekbereik.
Zoals u waarschijnlijk weet, is de functie INDIRECTE wordt gebruikt om een link te retourneren die wordt gegeven door een tekstreeks, en dat is precies wat we nu nodig hebben. Dus vervang in de bovenstaande formule stoutmoedig de uitdrukking door de functie IF koppelen met functie INDIRECTE. Hier is een combinatie VPR и INDIRECTE werkt prima met:
=VLOOKUP($D$2,INDIRECT($D3&"_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"_Sales");2;ЛОЖЬ)
Waar:
- $D$2 – dit is een cel met de naam van het product, deze is ongewijzigd vanwege de absolute link.
- $ D3 is de cel die het eerste deel van de regionaam bevat. In ons voorbeeld is dit FL.
- _Verkoop – het gemeenschappelijke deel van de naam van alle benoemde bereiken of tabellen. In combinatie met de waarde in cel D3 vormt dit de volledig gekwalificeerde naam van het vereiste bereik. Hieronder vindt u enkele details voor degenen die nieuw zijn in de functie: INDIRECTE.
Hoe INDIRECT en VERT.ZOEKEN werken
Laat me u eerst de syntaxis van de functie herinneren INDIRECTE (INDIRECT):
INDIRECT(ref_text,[a1])
ДВССЫЛ(ссылка_на_текст;[a1])
Het eerste argument kan een celverwijzing (A1- of R1C1-stijl), een bereiknaam of een tekenreeks zijn. Het tweede argument bepaalt welke stijl van link er in het eerste argument zit:
- A1als het argument is WARE CODE (TRUE) of niet gespecificeerd;
- R1C1, als FAS E (VALS).
In ons geval heeft de link de stijl A1, dus je kunt het tweede argument weglaten en je concentreren op het eerste.
Laten we dus teruggaan naar onze verkooprapporten. Als u het zich herinnert, is elk rapport een aparte tabel op een apart blad. Om de formule correct te laten werken, moet u uw tabellen (of bereiken) een naam geven en moeten alle namen een gemeenschappelijk deel hebben. Bijvoorbeeld als volgt: CA_Verkoop, FL_Verkoop, TX_Verkoop enzovoort. Zoals u kunt zien, is "_Sales" aanwezig in alle namen.
Functie INDIRECTE verbindt de waarde in kolom D en de tekstreeks "_Sales", en vertelt daarmee: VPR in welke tabel moet worden gezocht. Als cel D3 de waarde "FL" bevat, zoekt de formule in de tabel FL_Verkoop, indien “CA” – in de tabel CA_Verkoop enzovoort.
Het resultaat van de functies VPR и INDIRECTE zal het volgende zijn:
Als de gegevens zich in verschillende Excel-boeken bevinden, moet u de naam van het boek vóór het genoemde bereik toevoegen, bijvoorbeeld:
=VLOOKUP($D$2,INDIRECT($D3&"Workbook1!_Sales"),2,FALSE)
=ВПР($D$2;ДВССЫЛ($D3&"Workbook1!_Sales");2;ЛОЖЬ)
Als de functie INDIRECTE verwijst naar een andere werkmap, die werkmap moet geopend zijn. Als deze is gesloten, meldt de functie een fout. #REF! (#SSYL!).